                         SUBROUTINE DERIVS(NEW7)                                
C                                                                               
C     THIS  SUBROUTINE IS ENTERED ONCE AT THE BEGINNING  OF  EACH  CYCLE        
C     IT COMPUTES THE CURRENT VALUES OF DERIVATIVES OF CONVENTIONAL PARA        
C     METERS WITH RESPECT TO RIGID BODY PARAMETERS.    IF ANY INDEPENDEN        
C     PARAMETERS ARE THEMSELVES  ACTUALLY  DEPENDENT ON  OTHER PARAMETER        
C     THE DERIVATIVES WITH RESPECT TO THE TRUE INDEPENDENT PARAMETERS AR        
C     COMPUTED.   THEN THE INDEPENDENT PARAMETER DESIGNATOR ARE  REPLACE        
C     BY THEIR ROW INDICES IN THE NORMAL EQUATIONS MATRIX, AND THE  ARRA        
C              IS PACKED TO ELIMINATE ANY REDUNDANT RELATIONS.                  
C                                                                               
C                     WRITTEN BY       L. W. FINGER                             
C                                                                               
C     ADDITION OF  THERMAL VIBRATIONS OF FIFTH AND SIXTH ORDER   CUMULAN        
C                              COEFFICIENTS.                                    
C                                                                               
C                    BY  UDO ZUCKER  FEBRUARY 1980                              
C                                                                               
C     INPUT VARIABLES                                                           
C     ---------------                                                           
C                                                                               
C     NEW7  = NEW(7) IS FLAG FOR READING PARAMETER  SELECTION  AND CON -        
C                    STRAINT CARDS.                                             
C                                                                               
      DIMENSION  SAVE(60),KDEGN(2640),AA(2640)                                  
C                                                                               
      COMMON/XPAR/NPAR,ATOX(3,3),XTOA(3,3),PAR(60),PARNAM(2,60),IPAR(60)        
     &,IRPAR(60), OXYZ(3),SXYZ(3),OXP(3),T(3,3),EL(3,3),S(3,3),TRNS(3,3)        
     & ,TTRNS(3,3), TRANSI(3,3), TTRNSI(3,3), RTEM(3), BTEM(6), GTEM(10)        
      COMMON/LSMAT/ B(200),IEXT,IPARA(1000),MRANK,KCYL,LABEL(3),JSCRF(10        
     & ), NRSF, SIGMA, MDEGN, MAXIMA, IALFA(60), RDAMP(200), IDAMP(200),        
     & A(2200)                                                                  
      COMMON/A/BETA(6,60),G(3,3),ISOT(60),NATOM,TAG(2,60),TITLE(18),XYZ(        
     &3,60),PI,CR(10,60),DR(15,60),ALF(60),ITTYP(60)                            
      COMMON/IND23/IND2(2,6),IND3(3,10)                                         
      COMMON/TAPE/IN,INN,IOUT,ISC1,ISC2,ISC3,ISC4,ISC5,IPUN                     
      COMMON/D/ACALC,AIND(60),ANOM(2,20),BCALC,BIND(60),DADB(6,60),DADO(        
     & 60),DADX(3,60),DBDB(6,60),DBDO(60),DBDX(3,60),H(3),IH(3),ISCAT(2,        
     & 60),ISCL,MFSEL, OCCA(60), OCCUP(60), SCALE(10), SCAT(20),SITE(60)        
     & ,DADC(10,60), DBDC(10,60), DADD(15,60), DBDD(15,60),AMINUS,BMINUS        
     & ,DRDE(7),NDEGN,VORFAK,IPAREX(7),DAALFA(60),DBALFA(60)                    
C                                                                               
      EQUIVALENCE (SAVE,AIND),(KDEGN,AA,DADC(1,37))                             
C                                                                               
C                                                                               
      I1(K)              = MOD(K/256**3,256)                                    
      I2(K)              = MOD(K/256**2,256)                                    
      I3(K)              = MOD(K/256,256)                                       
      I4(K)              = MOD(K,256)                                           
      IPACK(L1,L2,L3,L4) = ((L1*256+L2)*256+L3)*256+L4                          
C                                                                               
C---- THE EXISTENCE OF FUNCTION STATEMENT IPACK IS DUE TO OVERLAY STRUC-        
C     TURE.                                                                     
C                                                                               
      MDEGN=2*NDEGN                                                             
C                                                                               
      IF(NPAR.EQ.0) GO TO 1001                                                  
C                                                                               
C                                                                               
C-----------------------------------------------------------------------        
C                                                                               
C---- TREATMENT OF SPECIAL PARAMETERS.                                          
C                                                                               
C>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>        
C                                                                               
C                               LOAD OVERLAY                                    
C                            CALL LLINK("R3OV1")                                
C                                                                               
C>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>        
C                                                                               
C---- TREATMENT OF SPECIAL PARAMETERS                                           
C                                                                               
      I=-1                                                                      
 10   I=I+2                                                                     
      IF(I1(KDEGN(I)).NE.0)GO TO 1001                                           
      IF(I2(KDEGN(I)).EQ.0.OR.I3(KDEGN(I)).EQ.0)GO TO 1000                      
      II=I2(KDEGN(I))                                                           
      NA=I3(KDEGN(I))                                                           
      NPMIN=I4(KDEGN(I))                                                        
      DO 20 J=I,MDEGN,2                                                         
      IF((J+2).GT.MDEGN)GO TO 22                                                
      IF(I3(KDEGN(J+2)).NE.NA)GO TO 22                                          
      IF(I2(KDEGN(J+2)).NE.II)GO TO 22                                          
 20   CONTINUE                                                                  
 22   NPMAX=I4(KDEGN(J))                                                        
C     I POINTS AT THE FIRST PARAMETER OF ATOM NA WHICH IS DEPENDENT ON          
C     SPECIAL PARAMETER II. J POINTS AT THE LAST.                               
C     GET SET DESIGNATOR, CLEAR ARRAYS, AND COMPUTE TRANSFORMATION.             
      IF(I1(IPAR(II)).EQ.0)GO TO 990                                            
      IF(I1(IPAR(II)).EQ.1)GO TO 30                                             
      CALL SPDERI(II,NA,NPMIN,NPMAX,I,J)                                        
      GO TO 990                                                                 
 30   ISET=I2(IPAR(II))                                                         
      DO 34 K=1,3                                                               
      OXYZ(K)=0.                                                                
      SXYZ(K)=0.                                                                
      OXP(K)=0.                                                                 
      DO 34 L=1,3                                                               
      T(K,L)=0.                                                                 
      EL(K,L)=0.                                                                
 34   S(K,L)=0.                                                                 
C     FILL IN VALUES FROM THIS SET.                                             
      DO 40 K23IL=1,NPAR                                                        
      K=K23IL                                                                   
      IF(I2(IPAR(K)).NE.ISET)GO TO 40                                           
      CALL FILLIN(K,I4(IPAR(K)),PAR(K),NA)                                      
 40   CONTINUE                                                                  
      CALL EULER(OXP(3),OXP(2),OXP(1),TRNS)                                     
C     DO WE NEED TO FILL IN XYZ                                                 
      IF(NPMIN.LE.4)GO TO 50                                                    
      CALL TRNSPS(TRNS,TRANSI)                                                  
      CALL MULMM(TRANSI,ATOX,TTRNSI)                                            
      DO 42 K=1,3                                                               
 42   RTEM(K)=XYZ(K,NA)-OXYZ(K)                                                 
      CALL MULMV(TTRNSI,RTEM,SXYZ)                                              
C     WHAT KIND IS INDEPENDENT PARAMETER?                                       
 50   IDEN=I4(IPAR(II))                                                         
      JDEN=(IDEN+2)/3                                                           
      IF(JDEN.GE.3)CALL MULMM(XTOA,TRNS,TTRNS)                                  
      GO TO (100,200,300,400,400,500,500,600,600,600),JDEN                      
C     SPECIAL ORIGIN                                                            
 100  DO 110 K=I,J,2                                                            
 110  AA(K+1)=1.                                                                
      GO TO 990                                                                 
C     ORIENTATION OF SPECIAL SYSTEM WRT CRYSTAL ORTHONORMAL.                    
 200  K=I                                                                       
      IF(IDEN-5)210,230,250                                                     
C     OMEGA ANGLE                                                               
 210  CALL DTDOMG(OXP(3),OXP(2),OXP(1),TRNS)                                    
 212  CALL MULMM(XTOA,TRNS,TTRNS)                                               
      IF(NPMIN.GE.5)GO TO 215                                                   
C     DERIVATIVES OF POSITION PARAMETERS WRT OMEGA,CHI, OR PHI.                 
      CALL MULMV(TTRNS,SXYZ,RTEM)                                               
 214  KK=I4(KDEGN(K))                                                           
      IF(KK.GE.5)GO TO 216                                                      
      AA(K+1)=RTEM(KK-1)                                                        
      K=K+2                                                                     
      IF(K-J)214,214,990                                                        
 215  IF(NPMIN.GE.11)GO TO 221                                                  
 216  IF(NPMAX.LE.4)GO TO 990                                                   
C     DERIVATIVES OF BETAS WRT OMEGA, CHI, OR PHI.                              
C     CORRECT SXYZ FOR LIBRATION.                                               
      CALL CORLIB(RTEM,EL,SXYZ)                                                 
      DO 218 L=1,6                                                              
      JK=IND2(1,L)                                                              
      JL=IND2(2,L)                                                              
 218  BTEM(L)=SKTLS(RTEM,JK,JL,T,EL,S)                                          
      CALL TFM2(TTRNS,BTEM,BTEM)                                                
 220  KK=I4(KDEGN(K))                                                           
      IF(KK.GE.11)GO TO 222                                                     
      AA(K+1)=BTEM(KK-4)                                                        
      K=K+2                                                                     
      IF(K-J)220,220,990                                                        
 221  CALL CORLIB(RTEM,EL,SXYZ)                                                 
 222  IF(NPMAX.LE.10)GO TO 990                                                  
C     DERIVATIVES OF GAMMAS WRT OMEGA, CHI, OR PHI.                             
      DO 224 L=1,10                                                             
      JK=IND3(1,L)                                                              
      JL=IND3(2,L)                                                              
      JM=IND3(3,L)                                                              
 224  GTEM(L)=TKTLS(RTEM,JK,JL,JM,EL,S)                                         
      CALL TFM3(TTRNS,GTEM,GTEM)                                                
 226  KK=I4(KDEGN(K))                                                           
      IF(KK.GT.20)GO TO 990                                                     
      AA(K+1)=GTEM(KK-10)                                                       
      K=K+2                                                                     
      IF(K-J)226,226,990                                                        
C     CHI ANGLE                                                                 
 230  CALL DTDCHI(OXP(3),OXP(2),OXP(1),TRNS)                                    
      GO TO 212                                                                 
C     PHI ANGLE                                                                 
 250  CALL DTDPHI(OXP(3),OXP(2),OXP(1),TRNS)                                    
      GO TO 212                                                                 
C     POSITION IN SPECIAL SYSTEM                                                
 300  K=I                                                                       
      IF(NPMIN.GE.5)GO TO 350                                                   
      DO 310 L=1,3                                                              
 310  BTEM(L)=0.                                                                
      BTEM(IDEN-6)=1.                                                           
      CALL MULMV(TTRNS,BTEM,RTEM)                                               
 320  KK=I4(KDEGN(K))                                                           
      IF(KK.GT.4)GO TO 360                                                      
      AA(K+1)=RTEM(KK-1)                                                        
      K=K+2                                                                     
      IF(K-J)320,320,990                                                        
C     WE SHALL NOW IGNORE THE DERIVATIVES OF BETAS AND GAMMAS WRT               
C     SXYZ, ZLTHOUGH THESE MAY ACTUALLY BE IMPORTANT. WE WILL FILL THEM         
C     IN LATER.                                                                 
 350  KK=I4(KDEGN(K))                                                           
 360  IF(KK.GT.10)GO TO 370                                                     
      AA(K+1)=0.                                                                
      K=K+2                                                                     
      IF(K-J)350,350,990                                                        
 365  KK=I4(KDEGN(K))                                                           
 370  IF(KK.GT.20)GO TO 990                                                     
      AA(K+1)=0.                                                                
      K=K+2                                                                     
      IF(K-J)365,365,990                                                        
C     ELEMENTS OF T TENSOR. ONLY BETAS INVOLVED.                                
 400  K=I                                                                       
      IDEN=IDEN-9                                                               
      JK=IND2(1,IDEN)                                                           
      JL=IND2(2,IDEN)                                                           
      DO 410 L=1,6                                                              
      JM=IND2(1,L)                                                              
      JN=IND2(2,L)                                                              
 410  BTEM(L)=D2KDT(JM,JN,JK,JL)                                                
      CALL TFM2(TTRNS,BTEM,BTEM)                                                
 420  KK=I4(KDEGN(K))                                                           
      IF(KK.GT.10)GO TO 990                                                     
      IF(KK.LT.5)GO TO 425                                                      
      AA(K+1)=BTEM(KK-4)                                                        
 425  K=K+2                                                                     
      IF(K-J)420,420,990                                                        
C     ELEMENTS OF L TENSOR. BETAS AND GAMMAS INVOLVED.                          
 500  K=I                                                                       
      IDEN=IDEN-15                                                              
      JK=IND2(1,IDEN)                                                           
      JL=IND2(2,IDEN)                                                           
      CALL CORLIB(RTEM,EL,SXYZ)                                                 
      IF(NPMIN.GT.10)GO TO 560                                                  
      DO 510 L=1,6                                                              
      JM=IND2(1,L)                                                              
      JN=IND2(2,L)                                                              
 510  BTEM(L)=D2KDL(RTEM,EL,S,JM,JN,JK,JL)                                      
      CALL TFM2(TTRNS,BTEM,BTEM)                                                
 520  KK=I4(KDEGN(K))                                                           
      IF(KK.GT.10)GO TO 560                                                     
      IF(KK.LT.5)GO TO 525                                                      
      AA(K+1)=BTEM(KK-4)                                                        
 525  K=K+2                                                                     
      IF(K-J)520,520,990                                                        
 560  DO 570 L=1,10                                                             
      JM=IND3(1,L)                                                              
      JN=IND3(2,L)                                                              
      JP=IND3(3,L)                                                              
 570  GTEM(L)=D3KDL(RTEM,EL,S,JM,JN,JP,JK,JL)                                   
      CALL TFM3(TTRNS,GTEM,GTEM)                                                
 580  KK=I4(KDEGN(K))                                                           
      IF(KK.GT.20)GO TO 990                                                     
      AA(K+1)=GTEM(KK-10)                                                       
      K=K+2                                                                     
      IF(K-J)580,580,990                                                        
C     ELEMENTS OF S TENSOR.                                                     
 600  K=I                                                                       
      IDEN=IDEN-21                                                              
      CALL CORLIB(RTEM,EL,SXYZ)                                                 
      IF(IDEN.GT.6)GO TO 605                                                    
      JK=IND2(1,IDEN)                                                           
      JL=IND2(2,IDEN)                                                           
      GO TO 608                                                                 
 605  JL=IND2(1,IDEN-3)                                                         
      JK=IND2(2,IDEN-3)                                                         
 608  DO 610 L=1,6                                                              
      JM=IND2(1,L)                                                              
      JN=IND2(2,L)                                                              
 610  BTEM(L)=D2KDS(RTEM,EL,JM,JN,JK,JL)                                        
      CALL TFM2(TTRNS,BTEM,BTEM)                                                
 620  KK=I4(KDEGN(K))                                                           
      IF(KK.GT.10)GO TO 650                                                     
      IF(KK.LT.5)GO TO 625                                                      
      AA(K+1)=BTEM(KK-4)                                                        
 625  K=K+2                                                                     
      IF(K-J)620,620,990                                                        
 650  DO 660 L=1,10                                                             
      JM=IND3(1,L)                                                              
      JN=IND3(2,L)                                                              
      JP=IND3(3,L)                                                              
 660  GTEM(L)=D3KDS(RTEM,EL,S,JM,JN,JP,JK,JL)                                   
      CALL TFM3(TTRNS,GTEM,GTEM)                                                
 670  KK=I4(KDEGN(K))                                                           
      IF(KK.GT.20)GO TO 990                                                     
      AA(K+1)=GTEM(KK-10)                                                       
      K=K+2                                                                     
      IF(K-J)670,670,990                                                        
 990  I=J                                                                       
 1000 IF(I+2.LT.MDEGN)GO TO 10                                                  
C-----------------------------------------------------------------------        
C                                                                               
C                                                                               
C---- CONVENTIONAL AND SPECIAL PARAMETER PART.                                  
C                                                                               
 1001 CONTINUE                                                                  
C                                                                               
C---- IF THERE ARE ANY SPECIAL PARAMETERS THAT DEPEND ON OTHER SPECIAL          
C     PARAMETERS,  THE DERIVATIVES MUST FIRST BE CORRECTED SO THAT ALL          
C     DERIVATIVES  REFLECT  ALL DEPENDENCIES. FIRST SAVE THE UNALTERED          
C     LIST                                                                      
C                                                                               
      REWIND ISC5                                                               
      WRITE(ISC5)MDEGN,(KDEGN(I),I=1,MDEGN)                                     
C                                                                               
C---- PRINT LIST OF DEPENDENCY CARDS IF NEW ONES READ      (OR SPECIAL          
C     PARAMETER TREATMENT)                                                      
C                                                                               
      IF(NPAR.NE.0.OR.NEW7.NE.0) CALL PDEGN(NEW7)                               
C                                                                               
      IF(NPAR.EQ.0) GO TO 2001                                                  
C                                                                               
C                                                                               
C----------------------------------------------------------------------         
C                                                                               
C---- SPECIAL PARAMETER TREATMENT                                               
C                                                                               
      DO 2000 I=1,MDEGN,2                                                       
      IF(I1(KDEGN(I)).NE.0)GO TO 2002                                           
      IF(I3(KDEGN(I)).NE.0)GO TO 2000                                           
      JJ=I4(KDEGN(I))                                                           
      II=I2(KDEGN(I))                                                           
      IJ=I+2                                                                    
      DO 1500 J=IJ,MDEGN,2                                                      
      IF(I1(KDEGN(J)).NE.0.OR.I2(KDEGN(J)).NE.II)GO TO 2000                     
      KK=I3(KDEGN(J))                                                           
      LL=I4(KDEGN(J))                                                           
      DO 1400 K=J,MDEGN,2                                                       
      IF(I1(KDEGN(K)).NE.0)GO TO 1500                                           
      IF(I4(KDEGN(K)).NE.LL.OR.I3(KDEGN(K)).NE.KK)GO TO 1400                    
      IF(I2(KDEGN(K)).EQ.JJ)AA(J+1)=AA(J+1)+AA(K+1)*AA(I+1)                     
 1400 CONTINUE                                                                  
 1500 CONTINUE                                                                  
 2000 CONTINUE                                                                  
 2002 DO 2990 I=1,MDEGN,2                                                       
      IF(I1(KDEGN(I)).NE.0)GO TO 2001                                           
      IF(I3(KDEGN(I)).NE.0)GO TO 2990                                           
      II=I4(KDEGN(I))                                                           
      DO 2980 J=I,MDEGN,2                                                       
      IF(I1(KDEGN(J)).EQ.0.AND.I2(KDEGN(J)).EQ.II)KDEGN(J)=0                    
 2980 CONTINUE                                                                  
 2990 CONTINUE                                                                  
C-----------------------------------------------------------------------        
C                                                                               
C                                                                               
C---- CONVENTIONAL AND SPECIAL PARAMETER PART.                                  
C                                                                               
C---- NOW ELIMINATE ALL DEPENDENT SPECIAL PARAMETERS, RESORT IF NECES-          
C     SARY, AND PACK THE LIST.                                                  
C     ALSO ELIMINATE INITIALIZING CONSTANTS AND ZERO DERIVATIVES.               
C                                                                               
 2001 L=MDEGN                                                                   
      J=0                                                                       
      DO 2100 I=1,L,2                                                           
      IF(KDEGN(I+1).EQ.0)GO TO 2100                                             
      IF(I3(KDEGN(I)).EQ.0.AND.I2(KDEGN(I)).EQ.0)GO TO 2100                     
      KDEGN(J+1)=KDEGN(I)                                                       
      KDEGN(J+2)=KDEGN(I+1)                                                     
      J=J+2                                                                     
 2100 CONTINUE                                                                  
      MDEGN=J                                                                   
C                                                                               
C---- REPLACE INDEPENDENT PARAMETER DESIGNATORS BY THEIR MATRIX POINTERS        
C                                                                               
      JPAR=0                                                                    
      JATOM=0                                                                   
      DO 2400 I=1,MDEGN,2                                                       
      K3=I3(KDEGN(I))                                                           
      K4=I4(KDEGN(I))                                                           
      IF(I1(KDEGN(I)).NE.0)GO TO 2320                                           
      J=I2(KDEGN(I))                                                            
      IF(J.EQ.0) K2=0                                                           
      IF(J.EQ.0) GOTO 2350                                                      
      K2=IRPAR(J)                                                               
      GO TO 2350                                                                
 2320 IF(I1(KDEGN(I)).EQ.JATOM)GO TO 2330                                       
      IF(JATOM.EQ.0)GO TO 2329                                                  
      IF(ISOT(JATOM)-1)2324,2322,2321                                           
 2321 IF(ISOT(JATOM).GT.2)JPAR=JPAR+15                                          
      IF(ISOT(JATOM).GT.3)JPAR=JPAR+21                                          
      IF(ISOT(JATOM).GT.4)JPAR=JPAR+28                                          
      JPAR=JPAR+10                                                              
 2322 JPAR=JPAR+5                                                               
 2324 JPAR=JPAR+5                                                               
 2329 JATOM=JATOM+1                                                             
      GO TO 2320                                                                
 2330 K1=I2(KDEGN(I))                                                           
      K2=IPARA(JPAR+K1)                                                         
 2350 KDEGN(I)=IPACK(0,K2,K3,K4)                                                
 2400 CONTINUE                                                                  
C                                                                               
C---- SHIFT ALTERED DEPENDENCY LIST UP INTO 'A' ARRAY.                          
C                                                                               
      DO 2500 I=1,MDEGN                                                         
 2500 A(I)=AA(I)                                                                
C                                                                               
      RETURN                                                                    
      END                                                                       
C                                                                               
                       SUBROUTINE PDEGN(NEW7)                                   
C                                                                               
C     SUBROUTINE TO PRINT OUT DEPENDENT  PARAMETER INFORMATION IF A  NEW        
C     DEPENDENCY LIST HAS BEEN READ IN OR  IF THE  DEPENDENCY  RELATION,        
C     BEING NONLINEAR, ARE SUBJECT TO CHANGE FROM ONE CYCLE TO THE NEXT.        
C              IF NEW7 SET TO FOUR NO PRINTING IS GIVEN.                        
C                                                                               
C                      WRITTEN BY L. W. FINGER                                  
C                                                                               
C                      MODIFIED BY  UDO ZUCKER                                  
C                                                                               
C     INPUT VARIABLE                                                            
C     --------------                                                            
C                                                                               
C     NEW7 = NEW(7)  FLAG FOR READING PARAMETER SELECTION AND CONSTRAINT        
C                    INFORMATION.                                               
C                                                                               
      DIMENSION SAVE(60),KDEGN(2640),AA(2640),ITEM(4,5)                         
C                                                                               
      COMMON/D/ACALC,AIND(60),ANOM(2,20),BCALC,BIND(60),DADB(6,60),DADO(        
     & 60),DADX(3,60),DBDB(6,60),DBDO(60),DBDX(3,60),H(3),IH(3),ISCAT(2,        
     & 60), ISCL,MFSEL, OCCA(60), OCCUP(60),SCALE(10),SCAT(20),SITE(60),        
     & DADC(10,60), DBDC(10,60), DADD(15,60), DBDD(15,60),AMINUS,BMINUS,        
     & DRDE(7),NDEGN,VORFAK,IPAREX(7),DAALFA(60),DBALFA(60)                     
      COMMON/XPAR/NPAR,ATOX(3,3),XTOA(3,3),PAR(60),PARNAM(2,60),IPAR(60)        
     &,IRPAR(60),OXYZ(3),SXYZ(3),OXP(3),T(3,3),EL(3,3),S(3,3),TRNS(3,3),        
     & TTRNS(3,3),TRANSI(3,3),TTRNSI(3,3),RTEM(3),BTEM(6),GTEM(10)              
      COMMON/TAPE/IN,INN,IOUT,ISC1,ISC2,ISC3,ISC4,ISC5,IPUN                     
C                                                                               
      EQUIVALENCE (SAVE,AIND),(KDEGN,AA,DADC(1,37))                             
C                                                                               
      I1(K) = MOD(K/256**3,256)                                                 
      I2(K) = MOD(K/256**2,256)                                                 
      I3(K) = MOD(K/256,256)                                                    
      I4(K) = MOD(K,256)                                                        
C                                                                               
  401 FORMAT(/28H0DEPENDENCY-LIST INFORMATION/1X,27(1H-)//                      
     & 34H0OLD DEPENDENCY LIST WILL BE USED.)                                   
 9200 FORMAT(/32H0DEPENDENT PARAMETER INFORMATION/1X,31(1H-)//1H )              
 9220 FORMAT(1X,5(4I3,2X,F8.3,2X))                                              
C                                                                               
C                                                                               
      IF(NEW7.GT.0)GO TO 200                                                    
C---- SPECIAL PARAMETER TREATMENT.                                              
      DO 100 I=1,NPAR                                                           
      IF(I1(IPAR(I)).NE.0)GO TO 200                                             
  100 CONTINUE                                                                  
      RETURN                                                                    
C                                                                               
  200 IF(NEW7.EQ.4) GOTO 400                                                    
C                                                                               
C---- NEW PARAMETERLIST OR UPDATES READ IN. CRACK THE INFO. OUT AND             
C     PRINT IT.                                                                 
C                                                                               
      WRITE(IOUT,9200)                                                          
      I=1                                                                       
  210 J=I+4                                                                     
      IF(J.GT.NDEGN)J=NDEGN                                                     
      DO 220 K=I,J                                                              
      L=K-I+1                                                                   
      M=2*K-1                                                                   
      ITEM(1,L)=I3(KDEGN(M))                                                    
      ITEM(2,L)=I4(KDEGN(M))                                                    
      ITEM(3,L)=I1(KDEGN(M))                                                    
  220 ITEM(4,L)=I2(KDEGN(M))                                                    
C                                                                               
C---- WRITE THE LIST                                                            
      WRITE(IOUT,9220)((ITEM(K,L-I+1),K=1,4),AA(2*L),L=I,J)                     
      I=I+5                                                                     
      IF(I.LE.NDEGN)GO TO 210                                                   
      RETURN                                                                    
C                                                                               
C---- OLD LIST OF CONSTRAINTS ARE USED.                                         
C                                                                               
  400 WRITE(IOUT,401)                                                           
C                                                                               
      RETURN                                                                    
      END                                                                       
                                                                                
                                                                                
                                                                                
                                                                                
                                                                                
                                                                                
                                                                                
                                                                                
