                      SUBROUTINE BODAN1(MBODAN)                                 
C                                                                               
C           BOND DISTANCE AND ANGLE SUBPROGRAM FOR REFINE                       
C             OUTPUT  DELETED  IF  ARGUMENT  NEGATIVE                           
C                                                                               
C                     WRITTEN BY L. W. FINGER                                   
C                                                                               
      COMMON/A/BETA(6,60),G(3,3),ISOT(60),NATOM,TAG(2,60),TITLE(18),XYZ(        
     &3,60),PI,CR(10,60),DR(15,60),ALF(60),ITTYP(60)                            
      COMMON/C/CELLP(3,4),ICENT,JCELL,NSYM,RMAT(3,3,24),TRANS(3,24)             
      COMMON/D/B(9),DXX(3),DXY(3),DXZ(3),  F(6),XP(3),XXP(3),XYP(3),YP(3        
     & ), ATEMP(65), NUMB(300), XPR(3,300),LIST,SN,SX,NXX(6),ZTEMP(390)         
      COMMON/E/DMAX,DMIN,RECELL(6),EXANG(6),EXTRAN(12)                          
      COMMON/TAPE/IN,INN,IOUT,ISC1,ISC2,ISC3,ISC4,ISC5,IPUN                     
C                                                                               
      EQUIVALENCE (NXX(1),NXL),(NXX(2),NYL),(NXX(3),NZL),(NXX(4),NXU),(N        
     & XX(5),NYU),(NXX(6),NZU)                                                  
                                                                                
    2 FORMAT(10X,2A3,3F10.5,54X,I5)                                             
    4 FORMAT(1H1//1X,22HBOND DISTANCES BETWEEN,F5.2,4H AND,F5.2,9HANGSTR        
     &OMS /1X,45(1H-)//10X,6HATOM 1,8X,1HX,9X,1HY,9X,1HZ,3X,6HATOM 2,8X         
     & ,1HX,9X,1HY,9X,1HZ,4X,8HDISTANCE,4X,6HNUMBER/1H )                        
    6 FORMAT(48X,2A3,3F10.5,F11.5,I10)                                          
    8 FORMAT(20H0ATOM ARRAY OVERFLOW)                                           
   10 FORMAT(1H1//12H BOND ANGLES/1X,11(1H-)//1H )                              
   12 FORMAT(1H0,3X,12HCENTRAL ATOM,7X,1HX,9X,1HY,9X,1HZ//9X,2A3,3F10.5/        
     &/15X,6HATOM 1,2X,6HNUMBER,10X,6HATOM 2,2X,6HNUMBER,10X,5HANGLE/1H         
     & )                                                                        
   14 FORMAT(15X,2A3,I6,12X,2A3,I6,F17.3)                                       
C                                                                               
      NUM=1                                                                     
      IF(ICENT)102,100,102                                                      
  100 NUM=2                                                                     
  102 IF(MBODAN)112,112,110                                                     
  110 WRITE(IOUT,4)DMIN,DMAX                                                    
  112 SX=DMAX**2                                                                
      SN=DMIN**2                                                                
      LIST=0                                                                    
                             DO 120 I=1,3                                       
  120 DXX(I)=DMAX*RECELL(I)                                                     
C                                                                               
C---- FIRST LOOP THROUGH ATOM LIST                                              
C                                                                               
                             DO 420 II=1,NATOM                                  
                             DO 130 J=1,3                                       
      DXY(J)=XYZ(J,II)+DXX(J)                                                   
  130 DXZ(J)=XYZ(J,II)-DXX(J)                                                   
      IF(II-1)135,170,135                                                       
C                                                                               
C---- CHECK IF ATOM II IN GENERATED LIST                                        
C                                                                               
  135                        DO 160 I=1,LIST                                    
      IF(NUMB(I)/64-II)160,140,160                                              
  140                        DO 150 J=1,3                                       
      IF(ABS(XPR(J,I)-XYZ(J,II))-0.00003)150,160,160                            
  150 CONTINUE                                                                  
      GO TO 190                                                                 
  160 CONTINUE                                                                  
C                                                                               
C---- ADD ATOM II TO LIST                                                       
C                                                                               
  170 LIST=LIST+1                                                               
      I=LIST                                                                    
      NUMB(LIST)=64*II+1                                                        
                             DO 180 J=1,3                                       
  180 XPR(J,LIST)=XYZ(J,II)                                                     
  190 IF(MBODAN)194,192,192                                                     
  192 WRITE(IOUT,2)(TAG(J,II),J=1,2),(XYZ(J,II),J=1,3),I                        
C---- LOOP THROUGH GENERATED LIST                                               
C                                                                               
  194                        DO 240 J=1,LIST                                    
      S=0.0                                                                     
                             DO 200 K=1,3                                       
  200 XP(K)=XYZ(K,II)-XPR(K,J)                                                  
                             DO 220 N=1,3                                       
      XZP=0.0                                                                   
                             DO 210 K=1,3                                       
  210 XZP=XZP+G(K,N)*XP(K)                                                      
  220 S=S+XZP*XP(N)                                                             
      IF((S-SX)*(SN-S))240,240,230                                              
  230 S=SQRT(S)                                                                 
      IJ=NUMB(J)/64                                                             
      IF(MBODAN)240,238,238                                                     
  238 WRITE(IOUT,6)(TAG(K,IJ),K=1,2),(XPR(K,J),K=1,3),S,J                       
  240 CONTINUE                                                                  
C                                                                               
C---- START SECOND LOOP THROUGH ATOM LIST                                       
C                                                                               
                             DO 420 JJ=1,NATOM                                  
C                                                                               
C---- START LOOP THROUGH SYMMETRY OPERATIONS                                    
C                                                                               
                             DO 420 J=1,NSYM                                    
                             DO 250 L=1,3                                       
      XP(L)=TRANS(L,J)                                                          
                             DO 250 M=1,3                                       
  250 XP(L)=XP(L)+RMAT(L,M,J)*XYZ(M,JJ)                                         
C                                                                               
C---- LOOP FOR CENTER OF SYMMETRY                                               
C                                                                               
                             DO 420 ITY=1,NUM                                   
      GO TO (280,260),ITY                                                       
  260                        DO 270 L=1,3                                       
  270 XP(L)=-XP(L)                                                              
C                                                                               
C---- LOOP THROUGH LATTICE POINTS                                               
C                                                                               
  280                        DO 420 KK=1,JCELL                                  
                             DO 290 L=1,3                                       
  290 XXP(L)=XP(L)+CELLP(L,KK)                                                  
C                                                                               
C----- SET TRANSLATION LIMITS                                                   
C                                                                               
                             DO 300 I=1,3                                       
      NXX(I)=5-IFIX(XXP(I)-DXZ(I))                                              
      NXX(I+3)=5.0+DXY(I)-XXP(I)                                                
      IF(NXX(I)-NXX(I+3))300,300,420                                            
  300 CONTINUE                                                                  
      NXU=NXX(4)                                                                
      NYU=NXX(5)                                                                
      NZU=NXX(6)                                                                
C                                                                               
C---- STEP THROUGH UNIT CELLS                                                   
C                                                                               
                             DO 410 IA=NXL,NXU                                  
      XYP(1)=XXP(1)+FLOAT(IA-5)                                                 
                             DO 410 IB=NYL,NYU                                  
      XYP(2)=XXP(2)+FLOAT(IB-5)                                                 
                             DO 410 IC=NZL,NZU                                  
      XYP(3)=XXP(3)+FLOAT(IC-5)                                                 
C                                                                               
C---- CHECK FOR ATOM DUPLICATION                                                
C                                                                               
                             DO 330 I=1,LIST                                    
      IF(NUMB(I)/64-JJ)330,310,330                                              
  310                        DO 320 L=1,3                                       
      IF(ABS(XYP(L)-XPR(L,I))-0.00003)320,330,330                               
  320 CONTINUE                                                                  
      GO TO  410                                                                
  330 CONTINUE                                                                  
C                                                                               
C---- NEW ATOM, COMPUTE DISTANCE                                                
C                                                                               
      S=0.0                                                                     
                             DO 340 K=1,3                                       
  340 YP(K)=XYZ(K,II)-XYP(K)                                                    
                             DO 360 N=1,3                                       
      XZP=0.0                                                                   
                             DO 350 K=1,3                                       
  350 XZP=XZP+YP(K)*G(K,N)                                                      
  360 S=S+XZP*YP(N)                                                             
      IF((S-SX)*(SN-S))410,410,370                                              
  370 S=SQRT(S)                                                                 
C                                                                               
C----  CHECK IF LIST ARRAYS FULL                                                
C                                                                               
      IF(LIST-300)390,380,380                                                   
  380 WRITE(IOUT,8)                                                             
      GO TO 410                                                                 
C                                                                               
C----- ADD ATOM TO LIST                                                         
C                                                                               
  390 LIST=LIST+1                                                               
      NUMB(LIST)=64*JJ+J                                                        
                             DO 400 K=1,3                                       
  400 XPR(K,LIST)=XYP(K)                                                        
      IF(MBODAN)410,402,402                                                     
  402 WRITE(IOUT,6)(TAG(K,JJ),K=1,2),XYP,S,LIST                                 
  410 CONTINUE                                                                  
  420 CONTINUE                                                                  
  430 IF(MBODAN-1)440,440,450                                                   
  440 RETURN                                                                    
C                                                                               
C---- COMPUTE BOND ANGLES                                                       
C                                                                               
  450 WRITE(IOUT,10)                                                            
      IJ=LIST-1                                                                 
C                                                                               
C---- LOOP THROUGH ATOMS                                                        
C                                                                               
                             DO 580 I=1,NATOM                                   
      WRITE(IOUT,12)(TAG(K,I),K=1,2),(XYZ(J,I),J=1,3)                           
C             FIRST LOOP THROUGH LIST                                           
                             DO 580 J=1,IJ                                      
                             DO 460 K=1,3                                       
  460 XP(K)=XPR(K,J)-XYZ(K,I)                                                   
      S=0.0                                                                     
                             DO 480 N=1,3                                       
      XXP(N)=0.0                                                                
                             DO 470 K=1,3                                       
  470 XXP(N)=XXP(N)+G(K,N)*XP(K)                                                
  480 S=S+XXP(N)*XP(N)                                                          
      IF((S-SX)*(SN-S))580,580,490                                              
  490 S=1.0/SQRT(S)                                                             
      NAT=NUMB(J)/64                                                            
      IK=J+1                                                                    
C                                                                               
C---- SECOND LOOP THROUGH LIST                                                  
C                                                                               
                             DO 570 K=IK,LIST                                   
      S2=0.0                                                                    
                             DO 500 N=1,3                                       
  500 YP(N)=XPR(N,K)-XYZ(N,I)                                                   
                             DO 520 N=1,3                                       
      XZP=0.0                                                                   
                             DO 510 M=1,3                                       
  510 XZP=XZP+YP(M)*G(M,N)                                                      
  520 S2=S2+XZP*YP(N)                                                           
      IF((S2-SX)*(SN-S2))570,570,530                                            
  530 S2=S/SQRT(S2)                                                             
      NTA=NUMB(K)/64                                                            
      CTH=0.0                                                                   
                             DO 540 M=1,3                                       
  540 CTH=CTH+XXP(M)*YP(M)                                                      
      CTH=CTH*S2                                                                
      TEMP=ABS(CTH)                                                             
      IF(TEMP-1.0)560,560,550                                                   
  550 CTH=CTH/TEMP                                                              
  560 CTH=180.0*ACOS(CTH)/PI                                                    
      WRITE(IOUT,14)(TAG(M,NAT),M=1,2),J,(TAG(M,NTA),M=1,2),K,CTH               
  570 CONTINUE                                                                  
  580 CONTINUE                                                                  
      RETURN                                                                    
      END                                                                       
C                                                                               
                SUBROUTINE ELVIB1(MELVIB,MBODAN)                                
C                                                                               
C              ELLIPSOIDS OF VIBRATION CALCULATION                              
C                                                                               
C                   WRITTEN BY L. W. FINGER                                     
C                                                                               
      COMMON/A/BETA(6,60),G(3,3),ISOT(60),NATOM,TAG(2,60),TITLE(18),XYZ(        
     &3,60),PI,CR(10,60),DR(15,60),ALF(60),ITTYP(60)                            
      COMMON/TAPE/IN,INN,IOUT,ISC1,ISC2,ISC3,ISC4,ISC5,IPUN                     
      COMMON/C/CELLP(3,4),ICENT,JCELL,NSYM,RMAT(3,3,24),TTRANS(3,24)            
      COMMON/D/B(3,3),D(3,3),F(6)  ,X(3,3),XP(3),ATEMP(65),NUMB(300),           
     &XPR(3,300),LIST,SN,SX,COEF(3),EIG(3),ROOT(3),YP(3),Y(3),ZTEMP(381)        
      COMMON/E/DMAX,DMIN,RECELL(6),EXANG(6),EXTRAN(12)                          
C                                                                               
    2 FORMAT(1H1//1X,23HELLIPSOIDS OF VIBRATION/1X,23(1H-)//1H )                
    4 FORMAT(///10X,14HELLIPSOID FOR ,2A3//15X,24HEQUIVALENT ISOTROPIC B        
     & = ,F8.4//20X,4HAXIS,10X,13HRMS AMPLITUDE,10X, 12HANGLE WITH A,5X,        
     &12HANGLE WITH B,5X,12HANGLE WITH C/1H )                                   
    6 FORMAT(///10X,2A3,25H IS NON-POSITIVE DEFINITE)                           
    8 FORMAT(20X,I3,12X,F11.6,3X,3F17.2)                                        
   10 FORMAT(/12X,56HRMS DISPLACEMENTS AND THERMAL CORRECTIONS TO BONDS         
     &FROM ,2A3,4H AT ,3F10.5   ///65X,9HDISTANCES,20X,12HDISPLACEMENT/         
     & /15X,4HATOM,7X,1HX,8X,1HY,8X,1HZ,6X,3HRAW,4X,5HLOWER,5X,6HRIDING         
     & ,2X,8HNON-CORR,2X,5HUPPER,3X,10HALONG BOND/1H )                          
   12 FORMAT(14X,2A3,9F9.5)                                                     
C                                                                               
      WRITE(IOUT,2)                                                             
      TFC=0.5/PI**2                                                             
                             DO 90 I=1,3                                        
      F(I)=G(I,I)                                                               
   90 Y(I)=SQRT(G(I,I))*RECELL(I)                                               
      F(4)=2.0*G(1,2)                                                           
      F(5)=2.0*G(1,3)                                                           
      F(6)=2.0*G(2,3)                                                           
C                                                                               
C---- START ATOM LOOP                                                           
C                                                                               
                             DO 420 I=1,NATOM                                   
      IF(ISOT(I))100,265,100                                                    
C                                                                               
C---- IGNORE ISOTROPIC ATOMS                                                    
C                                                                               
  100                        DO 110 K=1,2                                       
      B(K,K)=BETA(K,I)                                                          
      IJ=K+1                                                                    
                             DO 110 L=IJ,3                                      
      IK=IJ+L                                                                   
      B(K,L)=BETA(IK,I)                                                         
  110 B(L,K)=B(K,L)                                                             
      B(3,3)=BETA(3,I)                                                          
C                                                                               
C---- B NOW CONTAINS MATRIX OF THERMAL COEF. OF ATOM I                          
C     NOW COMPUTE D = G B                                                       
C                                                                               
                             DO 120 K=1,3                                       
                             DO 120 L=1,3                                       
      D(K,L)=0.0                                                                
                             DO 120 M=1,3                                       
  120 D(K,L)=D(K,L)+G(K,M)*B(M,L)                                               
C                                                                               
C---- SOLVE FOR EIGENVALUES OF D                                                
C                                                                               
      COEF(1)=D(1,1)+D(2,2)+D(3,3)                                              
      COEF(2)=D(1,1)*(D(2,2)+D(3,3))+D(2,2)*D(3,3)-D(1,2)*D(2,1)-D(1,3)*        
     & D(3,1)-D(2,3)*D(3,2)                                                     
      COEF(3)=D(1,1)*(D(2,2)*D(3,3)-D(2,3)*D(3,2))-D(1,2)*(D(2,1)*D(3,3)        
     & -D(3,1)*D(2,3))+D(1,3)*(D(2,1)*D(3,2)-D(3,1)*D(2,2))                     
C                                                                               
C---- EIGENVALUE EQUATION IS                                                    
C                                                                               
C     0 = -X**3 + COEF(1)*X**2-COEF(2)*X + COEF(3)                              
C                                                                               
      BISO=4.0/3.0*COEF(1)                                                      
      TEMP=COEF(2)-COEF(1)**2/3.0                                               
      TEMP1=(-2.0*COEF(1)**3+9.0*COEF(1)*COEF(2)-27.0*COEF(3))/27.0             
      TEMP2=-TEMP**3/27.0                                                       
      IF(0.25*TEMP1**2-TEMP2-1.0E-6)140,140,130                                 
C                                                                               
C---- ATOM NON-POSITIVE DEFINITE                                                
C                                                                               
  130 WRITE(IOUT,6)(TAG(K,I),K=1,2)                                             
      GO TO 420                                                                 
  140 IF(TEMP2.le.0.) TEMP2 =1.e-3                                          
      TEMP2=-0.5*TEMP1/SQRT(TEMP2)                                              
      TEMP3=ABS(TEMP2)                                                          
      IF(TEMP3-1.0)160,160,150                                                  
  150 TEMP2=TEMP2/TEMP3                                                         
  160 PHI=ACOS(TEMP2)/3.0                                                       
      IF(TEMP.GT.0.) TEMP = 0.                                                  
      TEMP=2.0*SQRT(-TEMP/3.0)                                                  
      COEF(2)=TEMP*COS(PHI+2.0*PI/3.0)+COEF(1)/3.0                              
      COEF(3)=TEMP*COS(PHI-2.0*PI/3.0)+COEF(1)/3.0                              
      COEF(1)=TEMP*COS(PHI)+COEF(1)/3.0                                         
C                                                                               
C---- ARRANGE ROOTS IN ORDER OF INCREASING SIZE                                 
C                                                                               
                             DO 180 N=1,2                                       
      IK=N+1                                                                    
                             DO 180 L=IK,3                                      
      IF(COEF(N)-COEF(L))180,180,170                                            
  170 TEMP=COEF(N)                                                              
      COEF(N)=COEF(L)                                                           
      COEF(L)=TEMP                                                              
  180 CONTINUE                                                                  
C                                                                               
C---- CALCULATE RMS DISPLACEMENTS                                               
C                                                                               
                             DO 190 K=1,3                                       
      IF(COEF(K))130,190,190                                                    
  190 ROOT(K)=SQRT(COEF(K)*TFC)                                                 
      WRITE(IOUT,4)(TAG(K,I),K=1,2),BISO                                        
C                                                                               
C---- START FINDING EIGENVECTORS                                                
C                                                                               
                             DO 200 K=1,3                                       
                             DO 200 L=1,3                                       
  200 X(K,L)=D(K,L)                                                             
                             DO 260 N=1,3                                       
                             DO 210 L=1,3                                       
  210 X(L,L)=D(L,L)-COEF(N)                                                     
C                                                                               
C---- X IS NOW G B - LAMBDA I                                                   
C                                                                               
      TEMP=1.0E-6                                                               
                             DO 220 ITMP=1,12                                   
      TEMP=TEMP*0.01                                                            
                             DO 220 K=1,3                                       
      M=K+1-3*(K/3)                                                             
      EIG(1)=RECELL(1)*(X(K,2)*X(M,3)-X(K,3)*X(M,2))                            
      EIG(2)=RECELL(2)*(X(K,3)*X(M,1)-X(K,1)*X(M,3))                            
      EIG(3)=RECELL(3)*(X(K,1)*X(M,2)-X(K,2)*X(M,1))                            
      FNC=EIG(1)**2+EIG(2)**2+EIG(3)**2                                         
C                                                                               
C---- CHECK FOR NULL VECTOR                                                     
C                                                                               
      IF(FNC-TEMP)220,220,230                                                   
  220 CONTINUE                                                                  
  230 FNC=SQRT(FNC+2.0*(EIG(1)*EIG(2)*RECELL(6)+EIG(1)*EIG(3)*RECELL(5)+        
     & EIG(2)*EIG(3)*RECELL(4)))                                                
                             DO 250 K=1,3                                       
      IF(FNC.EQ.0.) FNC = 1.0E-6                                                
      TEMP=EIG(K)/(FNC*Y(K))                                                    
      TEMP1=ABS(TEMP)                                                           
      IF(TEMP1-1.0)250,250,240                                                  
  240 TEMP=TEMP/TEMP1                                                           
  250 EIG(K)=180.0*ACOS(TEMP)/PI                                                
C                                                                               
C---- OUTPUT RESULTS                                                            
C                                                                               
  260 WRITE(IOUT,8)N,ROOT(N),EIG                                                
  265 IF(MELVIB-1)270,420,270                                                   
C                                                                               
C---- COMPUTE RMS DISP. ALONG BONDS AND THERMAL CORRECTION TO BO                
C                                                                               
  270 IF(MBODAN)290,280,290                                                     
C                                                                               
C---- BOND DISTANCES NOT AVAILABLE, COMPUTE AND SUPPRESS OUTPUT                 
C                                                                               
  280 CALL BODAN1(-1)                                                           
      MBODAN=1                                                                  
  290 WRITE(IOUT,10)(TAG(J,I),J=1,2),(XYZ(J,I),J=1,3)                           
C                                                                               
C---- TRANS IS MEAN SQUARE DISPLACEMENT OF ATOM I                               
C                                                                               
      TRANS=0.75*TFC*BISO                                                       
                             DO 410 J=1,LIST                                    
      SUM=0.0                                                                   
                             DO 300 K=1,3                                       
  300 XP(K)=XPR(K,J)-XYZ(K,I)                                                   
                             DO 320 N=1,3                                       
      YP(N)=0.0                                                                 
                             DO 310 K=1,3                                       
  310 YP(N)=YP(N)+G(K,N)*XP(K)                                                  
  320 SUM=SUM+YP(N)*XP(N)                                                       
      IF((SUM-SX)*(SN-SUM))410,410,330                                          
  330 DIST=SQRT(SUM)                                                            
      IF(ISOT(I))338,332,338                                                    
  332 DISP=SQRT(ABS(BETA(1,I))*0.25*TFC)                                        
      CORR1=0.50*ABS(BETA(1,I))*TFC                                             
      GO TO 358                                                                 
  338 PARA=0.0                                                                  
                             DO 350 N=1,3                                       
      XP(N)=0.0                                                                 
                             DO 340 K=1,3                                       
  340 XP(N)=XP(N)+YP(K)*B(N,K)                                                  
  350 PARA=PARA+XP(N)*YP(N)                                                     
      PARA=PARA*TFC/SUM                                                         
C                                                                               
C---- PARA IS THE MEAN SQUARE DISPLACEMENT ALONG BOND                           
C                                                                               
      DISP=SQRT(PARA)                                                           
      CORR1=ABS(TRANS-PARA)                                                     
  358 K=NUMB(J)/64                                                              
      IF(ISOT(K))370,360,370                                                    
  360 CORR2=0.50*ABS(BETA(1,K))*TFC                                             
      GO TO 400                                                                 
  370 TEMP=0.0                                                                  
                             DO 380 N=1,6                                       
  380 TEMP=TEMP+F(N)*BETA(N,K)                                                  
      TEMP=TFC*ABS(TEMP)                                                        
      TEMP1=0.0                                                                 
      L=MOD(NUMB(J),64)                                                         
                             DO 386 M=1,3                                       
      COEF(M)=0.0                                                               
                             DO 386 N=1,3                                       
  386 COEF(M)=COEF(M)+RMAT(N,M,L)*YP(N)                                         
                             DO 388 M=1,3                                       
  388 YP(M)=COEF(M)                                                             
                             DO 390 N=1,3                                       
  390 TEMP1=TEMP1+YP(N)**2*BETA(N,K)                                            
      TEMP1=TEMP1+2.0*(BETA(4,K)*YP(1)*YP(2)+BETA(5,K)*YP(1)*YP(3)+BETA(        
     & 6,K)*YP(2)*YP(3))                                                        
      TEMP1=ABS(TEMP1)*TFC/SUM                                                  
      CORR2=ABS(TEMP1-TEMP)                                                     
  400 RIDE=DIST+0.5*ABS(CORR1-CORR2)/DIST                                       
      UNCOR=DIST+0.5*(CORR1+CORR2)/DIST                                         
      BL=DIST+0.5*(SQRT(CORR1)-SQRT(CORR2))**2/DIST                             
      BU=DIST+0.5*(SQRT(CORR1)+SQRT(CORR2))**2/DIST                             
      WRITE(IOUT,12)(TAG(L,K),L=1,2),(XPR(L,J),L=1,3),DIST,BL,RIDE,UNCOR        
     &,BU,DISP                                                                  
  410 CONTINUE                                                                  
  420 CONTINUE                                                                  
C                                                                               
      RETURN                                                                    
      END                                                                       
                                                                                
                                                                                
                                                                                
